我的世界1.12版函数命令系统教学详解函数命令系统教程

　　我的世界1.12版本新增了函数命令这一内容，很多玩家觉得非常复杂，也有玩家发现这个命令可以完全脱离命令方块而存在，今天小编就为大家带来我的世界1.12版函数命令系统教学详解，感兴趣的盆友们快来看看吧！

　　1.12版函数命令系统教学详解

　　1.9的更新为我们带来了三色命令方块，让命令方块脱离了红石成为独立的体系，我们因此可以更好实现一些想法;时隔3个版本，MOJANG再次为我们带来惊人的变革。

　　1.12中，函数与进度系统的出现，让命令脱离命令方块——这句曾经说过的玩笑般的预言，正式成为可能。

　　函数系统的构成

　　函数系统的由来

　　函数(function)系统，是 MC 1.12 Pre-1 版本中新增的一个功能，它将原来进度系统中返回指令的部分单独提取出来，做成了现在的函数系统。

　　函数系统的形式

　　函数系统由命名空间和函数文件组成，这些文件保存在存档目录/data/functions/下。functions目录下的文件夹，称为命名空间，各个命名空间下存放不同的函数文件。实际上，命名空间就是方便我们编写者分类并管理各种函数文件。

　　函数文件是以.mcfunction为后缀名的文本文件，建议采用utf-8无BOM编码以防显示错乱。简单来讲，一个函数等价于一个多行命令方块，函数文件里面每一行写一条指令，当执行这个函数时，里面的指令会按行依次执行。如果在一个函数中调用其它函数，那么在同一游戏刻，被调用的函数中所有指令先执行完，再继续当前函数中后续的指令，就像插队一样，我们在后面对比命令方块时还会说到这个。

　　请注意：在 1.12 Pre-3 版本中存在一个严重漏洞，即命令执行体不能正确地通过execute传递到被调用的函数中去，这个漏洞有望在后续版本以及正式版修复。

　　以下是本文用到的一个函数系统的目录，带有"+"的表示为目录

　　+ functions

　　+ say

　　hi.mcfunction

　　bye.mcfunction

　　Text1.mcfunction

　　text2.mcfunction

　　+ system

　　+ process

　　_process.mcfunction

　　_main.mcfunction

　　player_tick.mcfunction

　　如何调用函数

　　在 1.12 中，MOJANG新增了function指令和一条名为gameLoopFunction的游戏规则来辅助我们使用函数系统。function指令的格式如下：

　　function <命名空间:函数名>

　　function <命名空间:函数名> <选择器>

　　这两条都是可行的。其中，if|unless是在1.12 pre-4加入的功能，后面我会解释到这个。我们先来说说第一种形式。例如上面的目录中，要调用system这个命名空间下的_main文件，就是输入这样的指令：

　　function system:_main

　　现在，我们来看一个例子例如say命名空间下的Text1.mcfunction和text2.mcfunction，里面分别写上这些内容

　　Text1.mcfunction

　　#这是一个范例，在function文件中可以用#来注释行。请注意，不能够使用//来注释!

　　say 1

　　function say:text2

　　say 2

　　text2.mcfunction

　　say 3

　　say 4

　　当我在系统后台输入function say:text1时，聊天框会出现这些内容：

　　[server] 1

　　[server] 3

　　[server] 4

　　[server] 2

　　也就是说，执行function指令的人，会把函数里面的指令依次执行——我在系统后台输入function指令，就是系统在执行，我自己输入function指令，就是我本人在执行。大家可能注意到了，函数中支持使用#进行注释(旧版本支持//注释，当前版本已经不再支持)，也就是说被注释行不会作为指令而执行，这一点有多方便相比不比我再说了。同时需要大家注意：函数中所有指令不能够以/开头。例如，你可以这样写：

　　say @s

　　但是不能这样写：

　　/say @s

　　最后有一点需要注意的是，在function指令中调用函数时，不区分大小写。例如前面say命名空间下的Text1.mcfunction，我在调用的时候写的是say:text1

　　然后是第二种形式，也就是带有if|unless的。我简单举两个例子，大家就知道是什么意思了。

　　say:tellraw.mcfunction

　　scoreboard objectives add timer dummy 计时器

　　scoreboard players add @s timer 1

　　function random:title if @s[score_timer_min=1200]

　　scoreboard players reset @s[score_timer_min=1200] timer

　　random:title.mcfunction

　　summon area_effect_cloud ~ ~ ~ {Tags:["rnd_title","rnd_title1"]}

　　summon area_effect_cloud ~ ~ ~ {Tags:["rnd_title","rnd_title2"]}

　　summon area_effect_cloud ~ ~ ~ {Tags:["rnd_title","rnd_title3"]}

　　summon area_effect_cloud ~ ~ ~ {Tags:["rnd_title","rnd_title4"]}

　　summon area_effect_cloud ~ ~ ~ {Tags:["rnd_title","rnd_title5"]}

　　entitydata @r[r=0,type=area_effect_cloud,tag=rnd_title] {CustomName:"rnd_title"}

　　execute @e[name=rnd_title,tag=rnd_title1] ~ ~ ~ tellraw @a[r=0,c=1] ["1"]

　　execute @e[name=rnd_title,tag=rnd_title2] ~ ~ ~ tellraw @a[r=0,c=1] ["2"]

　　execute @e[name=rnd_title,tag=rnd_title3] ~ ~ ~ tellraw @a[r=0,c=1] ["3"]

　　execute @e[name=rnd_title,tag=rnd_title4] ~ ~ ~ tellraw @a[r=0,c=1] ["4"]

　　execute @e[name=rnd_title,tag=rnd_title5] ~ ~ ~ tellraw @a[r=0,c=1] ["5"]

　　将say:tellraw放到主进程中

　　execute @a ~ ~ ~ function say:tellraw

　　则每位玩家每分钟将会看到1~5中随机一个数字出现在聊天框。也就是说，只有计时器分数满1200的人会执行后面的随机部分。那么很显然，带有if的意思就是，如果能找到后面的选择器，就执行这个函数，否则不执行。相当于testfor。

　　那么unless的意思也就很明显了：在找不到后面的选择器的时候，执行这个函数，相当于testfor+非门。

　　gameLoopFunction

　　讲完调用，就该讲讲高频了。玩命令方块的人都知道高频是实现许多功能的前提。在函数系统中，MOJANG 为我们提供了一条名为gameLoopFunction的游戏规则来实现高频。它的格式是

　　gamerule gameLoopFunction <命名空间:函数>

　　也就是说，你可以指定一个函数来高频执行，这个高频是20Hz的，也就是每一个游戏刻都会执行一遍。新建的存档如果没有执行过这条指令，而是用gamerule gameLoopFunction来查询的话，得到的返回值是-

　　为了方便，我们将这个规则简称为glf。在旧版本中，glf指定的函数，由系统(server)作为执行体;而在新的版本中，MOJANG 引入了虚拟执行体，例如将 say:text2 指定为glf时，每一个游戏刻得到的结果是这样的

　　[say:text2] 3

　　[say:text2] 4

　　也就是说，系统不再作为执行体，而是由虚拟的执行体代为执行。

　　关于 glf 多说两句。使用 glf 去高频执行一个函数，和使用 RCB(循环型命令方块，紫色那种)去执行，是不一样的。区别主要在于其更新顺序先后。一般而言不会造成严重影响，但是在某些情况会不一样。比如，使用 CB 能检测到生物的{HurtTime:10s}这个 NBT，而使用 glf 执行函数只能检测到的是{HurtTime:9s}，检测不到10，这是因为关于函数的更新，都放在了生物更新之后，而 CB 的更新则是在生物更新之前。详情可以看这里。按照 Searge 的说法，函数并不是命令方块的完全替代。这个说法，大家就见仁见智了。对我个人而言这个影响不大。

　　以上是函数系统的相关构成，以及如何调用函数。接下来我们来了解一下函数系统的模块分类。

　　函数系统的模块调用

　　对于一个完整的命令系统而言，模块一般可以分为三类：对执行顺序先后有要求的高频模块、对执行顺序先后无要求的高频模块、非高频模块。在函数系统中，我们同样可以将模块分成这三类。为了方便后续讲解。我们作这样的设定：

　　将 system:_main设为 glf ，并称之为主进程或者主时钟

　　对于上面讲到的三类模块，我们通过三种不同的方式去调用。

　　对执行顺序先后有要求的高频模块，在主进程中按照需要的顺序排列好来调用。对执行顺序先后没有要求的高频模块，在主进程中可以比较随意放置位置，但是一般不会考虑优先执行。特别地，如果这个模块是针对每一个玩家独立执行的，可以使用进度系统中的"tick"触发器来调用，而不需要放在主进程中。仅在特定情况下触发的非高频模块，在主进程中调用，但是辅以execute、scoreboard和选择器参数去控制其在合适的时候被调用，这里的选择器，包括了在1.12 pre-4中新增的if/unless的部分。

　　非高频模块在特定条件下激活，也在很大程度上减少了模块中大量重复出现execute的现象，并完全杜绝了超长的Conditional链，因为function中并不直接支持Conditional。不直接支持，说明可以间接支持，对吧。我们来看一个例子。

　　假设有红蓝两队，在开始前考虑到互殴问题不进行分队，而是采用挂tag的方式。

　　红队以tag=redTeam为标记，蓝队则以tag=blueTeam为标记，准备观战的玩家以tag=specTeam为标记

　　当玩家站在相应区域(红蓝两队的所有玩家还需要选择了职业)添加Ready的标记，视为准备就绪。

　　如果玩家不在相应区域时就移除Ready的标记。

　　选择了职业的玩家，其记分板项selectClass数值大于等于1

　　全部玩家准备就绪后，游戏进入倒计时，倒计时结束时游戏开始

　　倒计时未结束，有玩家脱离准备就绪的状态，则倒计时中断

　　条件比较多，我们先来看看怎么写这个模块，再进行分析。在这里，我们准备了一个名为gameStat的aec实体作为标记，所有游戏进程会以tag或者score的形式挂载到该实体上。请看指令部分

　　execute @p[tag=redTeam,score_selectClass_min=1] ~ ~ ~ execute @p[tag=blueTeam,score_selectClass_min=1] ~ ~ ~ scoreboard players tag @e[type=area_effect_cloud,name=gameStat,tag=notGaming] add allReady

　　execute @p[tag=!Ready,m=2] ~ ~ ~ scoreboard players tag @e[name=gameStat,type=area_effect_cloud,tag=notGaming] remove allReady

　　execute @p[tag=!Ready,m=2] ~ ~ ~ execute @e[name=gameStat,type=area_effect_cloud,tag=notGaming] ~ ~ ~ execute @s[tag=!allReady,score_waitTime_min=1] ~ ~ ~ title @a clear

　　execute @p[tag=!Ready,m=2] ~ ~ ~ execute @e[name=gameStat,type=area_effect_cloud,tag=notGaming] ~ ~ ~ execute @s[tag=!allReady,score_waitTime_min=1] ~ ~ ~ title @a reset

　　execute @p[tag=!Ready,m=2] ~ ~ ~ execute @e[name=gameStat,type=area_effect_cloud,tag=notGaming] ~ ~ ~ scoreboard players reset @s[tag=!allReady] waitTime

　　scoreboard players add @e[name=gameStat,tag=allReady] waitTime 1

　　execute @e[name=gameStat,score_waitTime=1,score_waitTime_min=1] ~ ~ ~ title @a times 10 140 10

　　execute @e[name=gameStat,score_waitTime=1,score_waitTime_min=1] ~ ~ ~ title @a subtitle [{"color":"aqua","text":"请玩家站在准备区域不要离开"}]

　　execute @e[name=gameStat,score_waitTime=1,score_waitTime_min=1] ~ ~ ~ title @a title [{"color":"yellow","text":"游戏即将开始"}]

　　execute @e[name=gameStat,score_waitTime=40,score_waitTime_min=40] ~ ~ ~ title @a subtitle [{"color":"aqua","text":"3"}]

　　execute @e[name=gameStat,score_waitTime=40,score_waitTime_min=40] ~ ~ ~ execute @a ~ ~ ~ playsound block.note.pling voice @p ~ ~ ~ 1 0

　　execute @e[name=gameStat,score_waitTime=60,score_waitTime_min=60] ~ ~ ~ title @a subtitle [{"color":"aqua","text":"2"}]

　　execute @e[name=gameStat,score_waitTime=60,score_waitTime_min=60] ~ ~ ~ execute @a ~ ~ ~ playsound block.note.pling voice @p ~ ~ ~ 1 0

　　execute @e[name=gameStat,score_waitTime=80,score_waitTime_min=80] ~ ~ ~ title @a subtitle [{"color":"aqua","text":"1"}]

　　execute @e[name=gameStat,score_waitTime=80,score_waitTime_min=80] ~ ~ ~ execute @a ~ ~ ~ playsound block.note.pling voice @p ~ ~ ~ 1 0

　　execute @e[name=gameStat,score_waitTime_min=100] ~ ~ ~ title @a times 10 30 10

　　execute @e[name=gameStat,score_waitTime_min=100] ~ ~ ~ title @a title [{"color":"gold","text":"游戏开始"}]

　　scoreboard players set @e[name=gameStat,type=area_effect_cloud,score_waitTime_min=100] gameStat 1

　　scoreboard players reset @e[name=gameStat,score_gameStat_min=1,score_gameStat=1] waitTime

　　scoreboard players tag @e[name=gameStat,score_gameStat_min=1,score_gameStat=1] remove allReady

　　execute @e[type=area_effect_cloud,name=gameStat,score_gameStat_min=1,score_gameStat=1] ~ ~ ~ function system:StartGame

　　接下来我们来慢慢分析。

　　首先是开始的条件。有红蓝两队，那么这两队都肯定需要有人，才能够开始，考虑到同一选择器中不能重复使用tag的参数，我们保留了区分队伍的参数，而不是区分是否准备就绪的参数。因此，第一条指令的意思是，当存在选了职业并选红队的玩家以及选了职业并选蓝队的玩家，我们给中心实体加上allReady这个标记，以表明可能满足开始条件。

　　至于满足条件吗?如果有未准备就绪的玩家，就说明不满足，那我们就让一个没有准备就绪的玩家来去掉allReady这个标记好了。

　　对于3~5行，我们放后面点讲。先看后面。满足开始条件以后，我们会给中心实体加分(使用waitTime这个记分板项)，在第一刻加分后出现提示文字提示准备开始，然后进入循环计时，最后计时满了，调用system:startgame这个函数来开始游戏(这里不是例子的部分，不作说明)。

　　那么回过头来看3~5行，这里明显是打断的部分。打断，就是要清掉提示文字、重置计时器。如果此时都还没有进行过加分，那么我们就不必进行那三条指令，因此可以看到中间有个选择器里有score_waitTime_min=1的参数加以限制。

　　重点来了，我们看到这3条指令前面相当长一串execute是重复的。因为在以前用cb写的时候，这里我使用了Conditional，而现在函数不直接支持Conditional，所以我用了一大堆execute，但是这里我们可以稍作修改，对不对?请看下面

　　execute @p[tag=redTeam,score_selectClass_min=1] ~ ~ ~ execute @p[tag=blueTeam,score_selectClass_min=1] ~ ~ ~ scoreboard players tag @e[type=area_effect_cloud,name=gameStat,tag=notGaming] add allReady

　　execute @p[tag=!Ready,m=2] ~ ~ ~ scoreboard players tag @e[name=gameStat,type=area_effect_cloud,tag=notGaming] remove allReady

　　execute @p[tag=!Ready,m=2] ~ ~ ~ execute @e[name=gameStat,type=area_effect_cloud,tag=notGaming] ~ ~ ~ execute @s[tag=!allReady,score_waitTime_min=1] ~ ~ ~ function system:cond_breakstartcount